ABC Syntax Zusammenstellung: Gerhard Schacherl

GRUNDLEGENDES ZUM QUELLTEXT

In einem einzelnen ABC-Musikstück darf es keine Leerzeilen geben.
Kommentarzeilen beginnen mit % (auch ohne nachfolgenden Kommentar möglich)
Sind mehrere Musikstücke in einem ABC-Quelltext vorhanden, muss mindestens eine Leerzeile dazwischen sein.
Ein Zeilenende im Quelltext bedeutet auch ein Zeilenende im Notenbild.

HEADER

Jede ABC-Datei hat einen sogenannten Header, der aus mehreren Zeilen besteht.
Die erste Zeile des Headers muss mit X: beginnen!
Die letzte Zeile des Headers muss mit K: beginnen!

X: Nummer des Musikstückes (Titels) innerhalb der Datei, die Nummer ist frei wählbar.
T: Titel des Musikstückes
T: (2. Zeile mit T:) Untertitel des Musikstückes
M: Taktart, z.B.: 3/4, 4/4, 6/8, ... od. none
L: Standardnotenlänge, z.B.: 1/1, 1/2, 1/4, 1/8, ...
Q: Tempo, z.B.: 1/4=120, 1/8=80, ...
K: Tonart, z.B.: C, G, Bb, Am, ...

Beispiel für einen minimalen Header

X:1
T:Viva la musica
M:4/4
L:1/8
K:F

Beispiel für einen Header incl. Tempobezeichnung

X:1
T:Viva la musica
M:4/4
L:1/8
Q:1/4=120
K:F

Der Header kann noch weitere Informationsfelder enthalten.

X:1
T:Viva la musica
T:(Kanon)
C:Michael Praetorius
O:um 1600
M:4/4
L:1/8
Q:1/4=120
K:F

In neueren Version von ABC2SVG wird der Header erst angeschrieben, wenn mindestens eine Note folgt. Zur Schreibweise der Noten siehe Tonhöhe

X:1
T:Viva la musica
T:(Kanon)
C:Michael Praetorius
O:um 1600
M:4/4
L:1/8
Q:1/4=120
K:F
F

TONART

Die Tonartbezeichnung im Header (K: ...) orientiert sich an den engl. Notennamen
K:C (= C-Dur)
Kreuztonarten:
K:G
K:D
K:A
K:E
K:B
K:F#
K:C#
Be-Tonarten:
K:F
K:Bb
K:Eb
K:Ab
K:Db
K:Gb
K:Cb
Auch die Angabe von Moll-Tonarten ist möglich:
Gm Dm Am ... Fm Bbm Ebm ...

Die Noten werden ohne Versetzungszeichen geschrieben!

Zur Schreibweise der Noten siehe Tonhöhe

X:1
T:Tonart
M:4/4
L:1/4
K:A
A,B,CD|EFGA||

TONHÖHE

Sind keine Notenschlüssel angegeben, werden die Noten je nach Tonhöhe automatisch in Violin- od. Bassschlüssel geschrieben.

Es gilt die englische Schreibweise der Notennamen: B = deutsche Note H

Große Oktav: C,, D,, E,, F,, G,, A,, B,,
Kleine Oktav: C, D, E, F, G, A, B,
Eingestrichene Oktav: C D E F G A B
Zweigestrichene Oktav: c d e f g a b
Dreigestrichene Oktav: c' d' e' f' g' a' b'

X:1
T:Tonhöhe
M:none
L:1/1
K:C
C,, D,, E,, F,, G,, A,, B,,
C, D, E, F, G, A, B,
C D E F G A B
c d e f g a b
c' d' e' f' g' a' b'

Eine zusammenfassende Darstellung von Klaviertastatur, Notennamen, ABC-Notennamen, MIDI-Notennummern und Tonausgabe gibt es hier.

TONLÄNGE Standardnotenlänge | Multiplikatoren| Divisoren | Kombinationen | Rhythm. Aufteilung

Standardnotenlänge

Die Standardnotenlänge wird mit L: angegeben: L:1/4, L:1/8, L:1/16, ...
Wird im ABC-Quelltext der Buchstabe für die Tonhöhe angeschrieben, wird im Notenbild die Note in der Standardlänge gezeichnet. Im ersten Beispiel wird L:1/4 als Standardlänge verwendet.

X:1
T:Standardnotenlänge 1/4
L:1/4
K:C
C D E F G A B c

Im nächsten Beispiel wird L:1/8 verwendet (für die meisten Musikstücke ideal).

X:1
T:Standardnotenlänge 1/8
L:1/8
K:C
C D E F G A B c

Standardnotenlänge - Multiplikatoren

Ein Multiplikator verlängert den Notenwert.
2 = doppelte Länge (das Doppelte von dem, was in L: angegeben ist)
3 = dreifache Länge
4 = vierfache Länge
usw.
Der Multiplikator muss nach dem Notennamen (ohne Leerzeichen) gesetzt werden,
z.B.: C4

X:1
T:Standardnotenlänge 1/4 und Multiplikatoren
L:1/4
K:C
C C2 C3 C4

X:1
T:Standardnotenlänge 1/8 und Multiplikatoren
L:1/8
K:C
C C2 C3 C4

Standardnotenlänge - Divisoren

Noten, die kürzer sind als der Standardnotenwert, werden so geschrieben:
/2 od. / = halber Standardnotenwert
/4 = ein Viertel des Standardnotenwertes
usw.
Anschreiben ohne Leerzeichen, z.B.: C/4

X:1
T:Standardnotenlänge 1/2 und Divisoren
L:1/2
K:C
C C/2 C/ C4

X:1
T:Standardnotenlänge 1/4 und Divisoren
L:1/4
K:C
C C/2 C/ C4

Standardnotenlänge - Kombinationen

Auch Kombinationen von Multiplikator und Divisor sind möglich.
z.B.: A3/2 = eingestrichenes A, 3-Sechzehntel-Note bei L:1/8
(Ein bisschen Mathematik: 3 mal 1/8, dividiert durch 2 = 3/16
oder: 1/8 dividiert durch 2 mal 3 = 3/16)

X:1
T:Standardnotenlänge - Kombinationen
M:none
L:1/8
K:C
G3/2

Rhythmische Aufteilung

Eine kleine Besonderheit der ABC-Musiknotation:
< teilt die Noten vor diesem Zeichen und hinter diesem Zeichen im rhythmischen Verhältnis von 1:3 auf
> teilt die Noten vor diesem Zeichen und hinter diesem Zeichen im rhythmischen Verhältnis von 3:1 auf

X:1
T:Rhythmische Aufteilung
M:4/4
L:1/4
K:C
GG G<G|GG G>G|G4|]

Zum Vergleich die Standardschreibweise:

X:1
T:Standardschreibweise
M:4/4
L:1/8
K:C
G2G2 G G3|G2G2 G3 G|G4|]

TAKT und TAKTSTRICHE

Die Taktart wird mit M: angegeben: M:4/4, M:6/8, M:3/16, ... none

| = Taktstrich
|| = Doppelter Taktstrich
|] = Endstrich

X:1
T:Takt und Taktstriche
M:4/4
L:1/4
K:C
CDEF|GABc||cdef|gabc'|]

NOTENSCHLÜSSEL

Sind keine Notenschlüssel angegeben, werden die Noten je nach Tonhöhe automatisch in Violin- od. Bassschlüssel geschrieben.

X:1
T:Notenschlüssel automatisch
M:4/4
L:1/4
K:C
GECG,|E,F,G,2|]

Schlüssel können aber auch im K-Feld (K:C treble od. K:C clef=treble),
bei Mehrstimmigkeit im V-Feld (V:1 bass od. V:1 clef=bass) oder mitten in der Notenzeile [K:treble] angegeben werden

Schlüsselnamen:
treble = Violinschlüssel
bass = Bassschlüssel
alto = C-Schlüssel
perc = Percussion

X:1
T:Notenschlüssel
M:4/4
L:1/4
K:C bass
C,2D,2|E,D,C,2|C2D2|EDC2| [K:treble]
C2D2|EDC2| [K:alto]C2D2|EDC2|]

PAUSEN

Pausen werden ähnlich behandelt wie Noten, nur dass statt eines Notennamens der Buchstabe z steht.

X:1
K:none
M:4/4
L:1/4
C4 | z4 | z2 z z/ z/4 c/4 |

Es gibt auch unsichtbare Pausen. Diese werden im Takt mitgezählt, sind aber im Notenbild nicht sichtbar. Sie haben statt des Buchstabens z den Buchstaben x

X:1
K:none
M:4/4
L:1/4
C4 | x4 | x2 x x/ x/4 c

VERSETZUNGSZEICHEN

Diatonische Melodien (= Töne aus der jeweiligen Tonleiter) erfordern keine Versetzungszeichen. Wenn andere (chromatische) Töne in der Melodie vorkommen, wird ein Zeichen vor den Notennamen gesetzt:

^ Kreuz
_ Be
= Auflösungszeichen

X:1
T:Versetzungszeichen
M:4/4
L:1/4
K:D
D E F G | A B c d |
d c B A | ^G A _B =B | d4||

TEMPO

Die Angabe des Tempos ist einerseits für das Abspielen per MIDI von Bedeutung, andrerseits erscheint die Tempoangabe auch im Notenbild.

Das Tempo wird im Header mit dem Q: - Feld angegeben.
Notenwert=Metronomangabe (beats per minute)

X:1
T:Andante
M:4/4
L:1/8
Q:1/4=80
K:C
CDEF GFED|C8||

Um die Darstellung des Tempos im Notenbild zu verhindern, gibt es die Angabe %%writefields Q 0

X:1
T:Andante
%%writefields Q 0
M:4/4
L:1/8
Q:1/4=80
K:C
CDEF GFED|C8||

FÄHNCHEN UND BALKEN

Mehrere Achtel od. Sechzehntel, ohne Abstand geschrieben, werden mit Balken gezeichnet. Ein Leerzeichen im Quelltext zwischen Paaren von Achteln od. Sechzehntel trennt den Balken auf. Einzelne Achtel od. Sechzehntel werden automatisch mit Fähnchen gezeichnet. Ein Leerzeichen ist dann nicht unbedingt erforderlich.

X:1
T:Fähnchen und Balken
M:4/4
L:1/8
Q:1/4=120
K:C
c2cceee2|ggggg4||c2cc eee2|ggggg4||
c2cc ee e2|gg ggg4||c2c c e ee2|g g g g g4||

HALTE- und BINDEBOGEN

Halte- und Bindebogen sehen zwar im Notenbild gleich aus, haben aber ganz verschiedene Bedeutungen:

Haltebogen

Ein Haltebogen (-) verbindet Noten gleicher Tonhöhe. Die zweite (verbundene) Note wird nicht gespielt, ihre Länge wird zur ersten Note addiert. Es entsteht also ein einzelner Ton, dessen Tonlänge sich aus den Längen beider Noten zusammensetzt. In diesem Beispiel: E (Länge 5/8) und C (Länge 6/4).
Mit Haltebogen können auch mehr als zwei Noten verbunden sein. Ihre Längen addieren sich zu einem einzelnen Ton.

X:1
T:Haltebogen
M:4/4
L:1/8
Q:1/4=100
K:C
A4G4|E4-EGFD|C8-|C4z4|]

Bindebogen

Ein Bindebogen ( (.....) ) verbindet Noten verschiedener Tonhöhe. Es handelt sich hier um eine spieltechnische Anweisung: legato (gebunden) spielen oder singen.
In der Vokalmusik kann ein Bindebogen auch eine andere Funktion haben: einer Silbe sind mehrere Noten zugeordnet. (siehe untenstehendes Lied "Das Wandern", vorletzter Takt)

X:1
T:Bindebogen
M:4/4
L:1/4
Q:1/4=120
K:C
CEGc|(BAGF|E4)||

TRIOLEN

(3 = 3 Schläge auf 2 Schläge (Triolen) für die nächsten drei Noten
(3:2:2 = 3 Schläge auf 2 Schläge für die nächsten 2 Noten

X:1
T:Triolen
M:4/4
L:1/8
Q:1/4=120
K:C
G2G2 (3 GGG G2 | (3 G2G2G2 G4 | (3:2:2 G2G GG G4||

In ähnlicher Weise werden auch Duolen, Quartolen, Quintolen ... behandelt.

X:1
T:Duolen
M:3/4
L:1/8
Q:1/4=120
K:C
C2D2E2| (2 F2D2 | E6|]

GITARRENAKKORDE

1. Methode:

Gitarrenakkorde stehen unter Anführungszeichen vor der Note, zu der sie gehören.

X:1
T:Gitarrenakkorde
M:4/4
L:1/4
Q:1/4=120
K:D
"D"DEFG|"G"AG"A7"FE|"D"D4|

2. Methode:

Gitarrenakkorde als eigenständige Stimme setzt die Kenntnis von Mehrstimmigkeit und unsichtbaren Pausen in ABC voraus, erlaubt dafür aber beliebige Akkordpositionen im Takt.

Zusätzlich kann mit einem geänderten %%score - Befehl die ganze Akkordstimme aus- und eingeschaltet werden.

X:1
T:Gitarrenakkorde
M:4/4
L:1/4
%%score (1 2)
Q:1/4=120
K:D
V:1
"D"x4|"G"x2"A7"x2|"G"x2"D"x2|]
V:2
DEFG|AGFE|D4|]

LIED- und STROPHENTEXTE

LIEDTEXT

Liedtextzeilen beginnen mit w: (kleines w). Die Verteilung der Silben unter die Noten erfolgt automatisch!

Trennung von Silben: - (Bindestrich)

Eine Silbe über 2 Noten: * (Stern direkt nach der Silbe, bewirkt: nächste Note überspringen,)
oder _ (Unterstrich direkt nach der Silbe, bewirkt: Textlängenstrich)
ACHTUNG: Satzzeichen und Bindestriche immer vor * bzw. _

Ausrichten von Strophennummern mit dem Tilde-Zeichen: 1.~

STROPHENTEXTE

Strophentexte sind Liedtexte am Ende des Notenblattes. Diese Textzeilen beginnen mit W: (großes W)

Die Strophennummern mit Punkt können ohne nachfolgendes Leerzeichen am Beginn einer Zeile stehen. Die Einrückung geschieht automatisch!

X:1
T:Das Wandern
C:Worte: Wilhelm Müller 1818 (1794-1827)
C:Weise: Karl Zöllner 1844 (1800-1860)
M:4/4
L:1/8
Q:1/4=120
K:F
V:1
C2|F3CA,2B,2|C3DC2F2|A3GF2G2|
w:1.~Das Wan-dern ist des Mül-lers Lust, das Wan-dern ist des
A3BA2F2|(A4G4)|F4z2CE|G2G2AG ^FG|
w:Mül-lers Lust, das Wan-_dern. Das_ muss ein schlech-_ter_
E2G2C2CE|G2G2AG ^FG|E2G2C2C2|
w:Mül-ler sein, dem_ nie-mals fiel_ das_ Wan-dern ein, dem
D2E2F2G2|A3GF2A2|(c4E4)|F4z|]
w:nie-mals fiel das Wan-dern ein, das Wan-_dern.
%
W:2. Vom Wasser haben wir´s gelernt...
W:Das hat nicht Ruh´ bei Tag und Nacht,
W:ist stets auf Wanderschaft bedacht...
W:
W:3. Das seh´n wir auch den Rädern ab...
W:Die gar nicht gerne stille steh´n,
W:und sich bei Tag nicht müde dreh´n...
W:
W:4. Die Steine selbst so schwer sie sind...
W:Sie tanzen mit dem muntern Rhein
W:und wollen gar noch schneller sein...
W:
W:5. O Wandern, Wandern meine Lust...
W:Herr Meister und Frau Meisterin
W:laßt mich in Frieden weiterzieh´n...

INFORMATIONSFELDER

Informationsfelder sind in der ABC-Musiknotation standardisiert und es gibt mehrere davon. Sie befinden sich im Header.
Das erste Informationsfeld des Headers ist X:
Die letzte Informationsfeld des Headers ist K:

X:1 Zeigt ein neues Musikstück an.
T:Viva la musica Titel
T:(Kanon) Untertitel
C:Michael Praetorius Composer
O:um 1600 Origin
N:transponiert um 2 Halbtöne Notes (= Info)
Q:1/4=100 Tempo (hier: 100 Viertelnoten pro min).
K:Eb Tonart (hier: Es-Dur)

X:1
T:Viva la musica
T:(Kanon)
C:Michael Praetorius
O:um 1600
N:transponiert um 2 Halbtöne
M:4/4
L:1/8
Q:1/4=100
K:Eb
B3AG2F E|D2E2D4|

Mit %%writefields können Felder ausgeschlossen oder angezeigt werden.
Mit %%titleformat können Felder im Titel plaziert werden.
Zusatz zur Feldbezeichnung: -1 = links, 0 = Mitte, 1 = rechts, Beistrich = neue Zeile

X:1
T:Viva la musica
T:(Kanon)
C:Michael Praetorius
O:um 1600
%%writefields Q 0
%%writefields N 1
%%titleformat T, C0 O1
M:4/4
L:1/8
N:transponiert um 2 Halbtöne
Q:1/4=100
K:Eb
B3AG2F E|D2E2D4|

TEXTE

Annotations | Zusatztexte | Sonderzeichen

Annotations

Annotations sind Texte, die an Elemente des Notensystems gebunden sind, z.B. an eine Note, eine Pause, einen Taktstrich, ...

"^Beliebiger Text"
Text oberhalb der Note, bzw. Pause
"_Beliebiger Text"
Text unterhalb der Note, bzw. Pause
"<Beliebiger Text"
Text vor der Note, bzw. Pause
">Beliebiger Text"
Text nach der Note, bzw. Pause
"@x,y Beliebiger Text"
Text in bestimmter Position zur Note, bzw. Pause
"@x,y Beliebiger Text, Zeile 1;Beliebiger Text, Zeile 2"
Text mehrzeilig: Trennung durch Strichpunkt

Zusatztexte vor/zwischen/nach den Notenzeilen

"%%text Beliebiger Text"
Text vor/zwischen/nach den Notenzeilen
"%%center Beliebiger Text"
Zentrierter Text

Mit %%textoption ... können Textabsätze formatiert werden.

X:1
T:Zusatztexte (Annotations und andere Texte)
M:4/4
L:1/4
K:C
"^oben"C "_unten"D "<vor"E ">nach"F | "@-10,20 Bel. Pos."G4|"@-10,20 Zeile1;Zeile2"C4|]
%
%%text Textzeile linksbündig
%%center Textzeile zentriert
%%textoption right
%%text Textzeile rechtsbündig
%%textoption left
%%text Textzeile wieder linksbündig

Sonderzeichen

Für genaue Schreibweise siehe auch den Quelltext der Seite!

abc2svg

Eingabe-Möglichkeiten für Unicode-Zeichen:
© = Zeichen kopiert aus Text oder mit Tastatur (ALT + Nr) eingegeben
\u00a9 = \u + hexadezimale Unicode-Nummer (s. Unicode table)
&#169; = HTML-Code (&# + Unicode-Dezimalnummer + Semikolon)
&#x00a9; = CSS Code (&#x + hexadezimale Unicode-Nummer + Semikolon)
Für einige Zeichen gibt es in ABC genormte Ersatzzeichen,
die heute noch funktionieren, jedoch als veraltet gelten:
ä = \"a, ö = \"o, ü = \"u, Ä = \"A, ... å = \oa, Å = \oA, ß = \ss

In abc2svg nicht verwendbar (Error!) sind HTML-Entities wie '&copy;'
Auch die Unterstützung für Oktalcodes wurde in abc2svg eingestellt, mit wenigen Ausnahmen für Vorzeichen!

X:1
T:Sonderzeichen im Text \u263a
C:© G. Schacherl
M:3/4
L:1/4
Q:1/4=120
K:Am
%%text Eingabe-Möglichkeiten für Unicode-Zeichen:
%%text ©  = Zeichen kopiert aus Text oder mit Tastatur (ALT + Nr) eingegeben
%%text \u00a9 = \u005cu + hexadezimale Unicode-Nummer
%%text © = HTML-Code (&# + Unicode-Demimalnummer + Semikolon)
%%text © = CSS Code (&#x + hexadezimale Unicode-Nummer + Semikolon)
%%text Für einige Zeichen gibt es in ABC genormte Ersatzzeichen,
%%text die heute noch funktionieren, jedoch als veraltet gelten:
%%text ä = \"a, ö = \"o, ü = \"u, Ä = \"A, ... å = \oa, Å = \oA, ß = \ss
%%text
%%text In abc2svg nicht verwendbar (Error!) sind HTML-Entities wie ©
%%text Auch die Unterstützung für Oktalcodes wurde in abc2svg eingestellt,
%%text mit wenigen Ausnahmen für Vorzeichen!
Ace|"^(\202)"Bdf|ea"^(\201)"g|a3||
w:*** \u2191 ** **\u2191 *
%%text Die Vorzeichen ♭ und ♯ in diesem Stück sind optional

abcm2ps

X:1
%<!--
T:Sonderzeichen im Text
%%text Für abcm2ps kann man Oktal-codes von "Latin1"-Characters verwenden!
© G. Schacherl
M:3/4
L:1/4
%%text Einige Zeichen aus "Latin1": è \350 é \351 « \253 » \273 ® \256  © \251  ...
Q:1/4=120
K:D
def| efg|fed|cde||
w:ä \"a \344 å \oa  \345 Ä \"A \304 Å \oA \305
w:ö \"o \366 ü \"u \374 Ö \"O \326 Ü \"U \334
w:ß \ss \337 . . . . . . . . .
%-->

DYNAMIKZEICHEN (Lautstärke)

!pp! = pianissimo
!p! = piano
!mf! = mezzoforte
!f! = forte
!ff! = fortissimo
!<(! = cresz. Beginn (vor der ersten Note)
!<)! = cresz. Ende; (vor der letzten Note)
!>(! = decresz. Beginn (vor der ersten Note)
!>)! = decresz. Ende (vor der letzten Note)

Dynamikzeichen werden beim Abspielen nicht berücksichtigt. Ausnahme ABC2MIDI (siehe Kapitel Programme)

X:1
T:Dynamikzeichen
M:3/4
L:1/8
Q:1/4=120
K:C
!p!C2D2E2-|E2D2C2|D2(GFED)|C6|
!f!A2A2A2|G6| !<(!F2(GFED)|!<)!!p!C6|]

SYMBOLE (decorations)

decorations od. expressions

Hier ist eine kleine Auswahl davon:
. (Punkt vor der Note) = staccato
!accent! = Akzent
!breath! = Atemzeichen
!fermata! = Fermate
!invertedfermata! = Fermate unten
!shortphrase! = Trennungszeichen zwischen Phrasen
!tenuto! = Tenuto (Note über volle Länge aushalten)
!trill! = Triller-Zeichen

X:1
T:Sonstige Zeichen
M:3/4
L:1/4
Q:1/4=120
K:C
!tenuto!C!tenuto!D.E.F|G2!fermata!!breath!c2| !accent!FE!trill!D2|C4|]

AKKORDE

Akkorde sind 2-, 3-, und mehrstimmige Klänge. Sie werden in eckige Klammern gesetzt. Multiplikatoren oder Divisoren werden nach der schließenden Klammer geschrieben.
Nicht zu verwechseln mit der Mehrstimmigkeit von unabhängigen Stimmen!

X:1
T:Akkorde
M:4/4
L:1/4
K:C
[EGc]2 [GB] [FA] | [CEG]4 |]

MEHRSTIMMIGKEIT Voices | Voice Overlay | Score | Stimmenbezeichnung

VOICES

Bis zu 16 Stimmen ("Voices") sind möglich. Jede Stimme beginnt mit V: gefolgt von einer frei wählbaren Zahl. Allfällige Schlüsselnamen folgen: treble (Violinschlüssel), bass (Bassschlüssel)
Stimmen und Abstände der Notenzeilen werden automatisch ausgerichtet.

X:1
T:Voices
M:4/4
L:1/8
K:D
V:1
A2F2GF2E|D8|]
V:2 bass
D4B,2C2|D8|]

VOICE OVERLAY

Wenn nur kurzzeitig (für einen Takt) Zweistimmigkeit gewünscht ist, kann ein einzelner Takt so geschrieben werden: Noten für 1. Stimme & Noten für 2. Stimme, z.B.:

X:1
T:Voice overlay
M:4/4
L:1/4
K:C
CEGc | zc2B & E2D2 | c4 & C4 ||

SCORE (STAVES)

Der Hit in der ABC-Musiknotation!!!
Eine einzige Zeile eingefügt, und das Notenbild schaut völlig anders aus.
%%score ermöglicht verschiedene Kombinationen von Stimmen im Notenbild:

%%staves (der ältere der beiden Befehle) bewirkt fast das gleiche wie %%score mit einem Unterschied: %%staves {(1 2) 3} zeichnet durchgehende Taktstriche (bei %%score mit | erreichbar).
Laut "abc music standard" sollte %%score verwendet werden.

X:1
T:score
M:4/4
L:1/8
%%score [(1 2) | 3]
K:D
V:1
A2F2GF2E|D8|]
V:2
D4B,2C2|D8|]
V:3 bass
F,2D,2G,2A,2|D,8|]

STIMMENBEZEICHNUNG

V:1 name="Violine" bewirkt Stimmenbezeichnung in der 1. Notenzeile
V:1 sname="Vl." bewirkt Stimmenbezeichnung (Kurzbezeichnung) in den folgenden Notenzeilen
V:1 name="Violine" sname="Vl." bewirkt Stimmenbezeichnungen und Kurzbezeichnung in allen Notenzeilen

X:1
T:Stimmenbezeichnung
M:4/4
L:1/8
%%score [1 | 2 | 3]
K:D
V:1 name="Violine 1" sname="V. 1"
d2A2BA2G|F6z2|
A2F2GF2E|D8|]
V:2 name="Violine 2" sname="V. 2"
F2F2GF2E|D6z2|
D4B,2C2|D8|]
V:3 bass name="Violoncello" sname="Vcl."
D,4D,4|D,2F,2A,2G,2|
F,2D,2G,2A,2|D,8|]

WIEDERHOLUNGEN und VOLTA-KLAMMERN

|: .................. :| Wiederholungszeichen
[1 = 1. Schluss
[2 = 2. Schluss
["1., 2." = Schlussbezeichnung (mit eigenem Text)

!segno! = Segno-Zeichen
!D.C.! = da capo
!D.S.! = dal segno
!coda! = Coda-Zeichen
!fine! = Fine (Schluss)

%%repbra 0 verhindert das Zeichnen von Volta-Klammern in der jeweiligen Stimme

X:1
T:Wiederholung und Volta-Klammern
M:4/4
L:1/4
K:C
V:1
CEGc|CEGc|
BAGF | [1 EFG2 :| [2 E4 |]
V:2 bass
%%repbra 0
C,4|E,4|
G,2B,,2| [1 C,D,E,2 :| [2 C,4 |]

X:1
T:Segno, D.S. und Fine
%%linewarn 0
M:4/4
L:1/4
K:C
!segno!G2EF|G2C2|DEFG|!fine!E4|]
EBBB|A4|DAAA|G4!D.S.!||

PARTS

Gliederung eines Stückes in Teile und Benennung derselben mit Buchstaben.
2 Schreibweisen: als extra Zeile, z.B.: P:A od. als sogenanntes Inline-Feld [P:A] mitten im Notentext.

Part-Bezeichnungen, die im Header vorkommen, bedeuten den Ablauf des Stückes, z.B.:
P:ABA = Part A, Part B, Part A
Die Parts im Header müssen natürlich ihre Entsprechung in den Noten haben.

Mit %%partsbox 1 erhalten die Partbezeichnungen im Notenbild eine Umrandung.

Für ABCM2PS gilt:
Parts werden in der 1. vorkommenden Stimme definiert und können in den restlichen Stimmen ebenfalls eingezeichnet werden. In ABCM2PS kann die Part-Bezeichnung länger als ein Buchstabe sein, z.B. P:Refrain

Für ABC2SVG gilt:
Parts werden beim Abspielen berücksichtigt, wenn sich im Header eine entsprechende Anweisung befindet.

Für ABCMIDI gilt:
Parts werden vor der 1. Stimme (Voice) definiert. Dann folgen alle Stimmen dieses Parts. Nur der 1. Buchstabe der Part-Bezeichnung wird interpretiert.

X:1
T:Parts
P:ABAB
%%partsbox 1
M:3/4
L:1/4
Q:1/4=140
K:Bb
V:1
P:A
B,DF|FED|CB,C|B,3|
B,DF|BBB|AGA|FGA|
P:B
B2G|FD2|E2C|DF2|
B2G|FDB,|CDC|B,3|]

TAKTNUMMER

Taktnummern werden meist am Beginn einer Notenzeile geschrieben. Das lässt sich erreichen mit %%measurenb 0
Andere Zahlen als Null bewirken Anschreiben der Taktnummer nach x Takten.

X:1
T:Menuett
T:(Ausschnitt)
%%measurenb 0
C:J. S. Bach
M:3/4
L:1/8
Q:1/4=100
K:G
d2GABc|d2G2G2|e2cdef|g2G2G2|
c2dcBA|B2cBAG|F2GABG|{B}A6|
d2GABc|d2G2G2|e2cdef|g2G2G2|
c2dcBA|B2cBAG|A2BAGF|G6:|

LAYOUT

Das Layout einer ABC-Datei kann durch spezielle Befehle beeinflusst werden.
In ABCM2PS sind alle Befehle implementiert. Eine Beschreibung aller Formatbefehle gibt der Autor auf seiner Internetseite:
http://moinejf.free.fr/abcm2ps-doc/index.html (englisch)

Beispiele:

%BEFEHLE
%%scale 0.7
%%pagewidth 21cm
%%pageheight 29.6cm
%%topmargin 2.0cm
%%botmargin 2.0cm
%%leftmargin 2.0cm
%%rightmargin 2.0cm
%%vocalfont Helvetica 14
%%wordsfont Times-Roman 14
%%wordsspace 0.5cm
%%gchordfont Helvetica-Bold 16
%%measurenb 0
%%staffsep 3cm
%%sysstaffsep 2.5cm
%%titleformat T, Q-1 O1

%ERLÄUTERUNGEN
%ganzes Stück skalieren (0.75 ist Standard)
%Seitenbreite
%Seitenhöhe
%Oberer Rand
%Unterer Rand
%Linker Rand
%Rechter Rand
%(Postscript-)Schrift für Liedtexte
%(Postscript-)Schrift für Strophentexte
%Abstand (oben) vor Strophentexten
%(Postscript-)Schrift für Gitarrenakkorde
%Taktnummern am Beginn jeder Notenzeile schreiben
%Abstand der Notensysteme
%Abstand der Notenzeilen im gleichen System
%Titelzeilen in Blöcken formatieren

X:1
T:Billy boy
O:English Folksong
%%bgcolor #f0f0f0 %nur für abc2svg!
%%scale 0.6
%%pagewidth 16cm
%%pageheight 29.6cm
%%leftmargin 1.0cm
%%rightmargin 1.0cm
%%vocalfont Helvetica 14
%%wordsfont Times-Roman 16
%%gchordfont Helvetica-Bold 16
%%measurenb 0
%%staffsep 3cm
%%titleformat T, Q-1 O1
M:4/4
L:1/8
Q:1/4=100
K:C
V:1 octave=-1
(ef)|"C"g2g gc'2e f|g2g ag2(ef)|
w:1.~Oh, _ where have you been, Bil-ly Boy, Bil-ly Boy? Oh, _
g2g gc'2f e|"G"e d-d2z2d e|
w:where have you been, char-min' Bil-ly? _ I have
f f f f f2 g f|"C"(ed) e fg2c' a|
w:been to seek a wife, She's the joy _ of my life. She's a
g2e g "G"g f d B|"C"d c-c2z2|]
w:young thing and can-not leave her mo-ther. _
W:2.Did she bid you to come in, Billy Boy, Billy Boy?
W:Did she bid you to come in, charmin’ Billy?
W:Yes, she bade me to come in, and to kiss her on the chin.
W:She's a young thing and cannot leave her mother.
W:3.Did she offer you a chair, Billy Boy, Billy Boy?
W:Did she offer you a chair, charmin’ Billy?
W:Yes, she offered me a chair, but the bottom wasn't there,
W:She's a young thing and cannot leave her mother.
%%begintext
(Ausgewählte Strophen)
%%endtext

ZUSÄTZLICHER PLATZ ZWISCHEN NOTEN OD. PAUSEN

y mit/ohne anschließender Zahl (in Punkten) schafft Platz!
Für ABCJS gilt: bei mehrstimmigen Stücken in allen Notensystemen einsetzen!

X:1
T:Zusätzlicher Platz zwischen Noten od. Pausen
M:4/4
L:1/4
%%staves (1 2)
K:C
V:1
CDEF|GFED|C4-|C4|]
V:2
"C"x4|"G7"x4|"FMaj7"x2 y50"CMaj7/E"x "Dm"x|"C"x4|]

MIDI ABC2SVG | ABC2MIDI | ABCJS

MIDI in ABC2SVG

%%MIDI program 20

%%MIDI channel 10

X:1
T:MIDI
M:4/4
L:1/4
Q:1/4=70
%%score [1 2]
K:C
V:1
%%MIDI program 74
[EGc][EAc][FAc][DGB]|[EGc]2z2|]
V:2 bass
%%MIDI program 43
C,A,F,G,|C,2z2|]

MIDI in ABC2MIDI

Die folgenden Befehle gelten für das Programm ABC2MIDI und daher auch für jene "All-in-one-Programme", die ABC2MIDI enthalten

%BEFEHLE (Auswahl)
%%MIDI channel 10

%%MIDI program 17

%%MIDI control 7 64

%ERLÄUTERUNGEN
%MIDI channel,        hier: Kanal 10 (=Schlagzeug),
                      zu setzen nach der Stimmenbez. V:
%MIDI program change, hier: Nummer 17,
                      zu setzen nach der Stimmenbez. V:
%MIDI control,        hier: 7 = Lautstärke, 64 = Wert

X:1
T:MIDI
M:4/4
L:1/4
Q:1/4=70
%%score [1 2]
K:C
V:1
%%MIDI program 19
[EGc][EAc][FAc][DGB]|[EGc]2z2|]
V:2 bass
%%MIDI program 32
C,A,F,G,|C,2z2|]

ABC2MIDI ist ein Kommandozeilenprogramm. Obiger ABC-Quelltext müsste als ABC-Datei gespeichert (z.B.: test.abc) und dann im Kommandozeilen-Modus an ABC2MIDI übergeben werden:
abc2midi test-abc
Das Ergebnis wäre eine MIDI-Datei (test.mid), die mit Bordmitteln von Windows abspielbar ist.

MIDI in ABCJS

X:1
T:MIDI
M:4/4
L:1/4
Q:1/4=70
%%score [1 2]
K:C
V:1
%%MIDI program 19
[EGc][EAc][FAc][DGB]|[EGc]2z2|]
V:2 bass
%%MIDI program 32
C,A,F,G,|C,2z2|]

Dieser Code ist in ABCJS abspielbar. ABCJS arbeitet ebenfalls mit Soundfonts.

X:1
T:Schlagzeugstimme (Variante mit \%\%map)
%%beginsvg
 <defs>
 <path id="x_head" d="m-3 -3l6 6m0 -6l-6 6"
    class="stroke" style="stroke-width:1.2"/>
 </defs>
%%endsvg
%%map drumset ^D, print=f heads=x_head
%%map drumset C,, print=F
%%map drumset E,, print=c
M:4/4
L:1/4
Q:1/4=180
K:D
V:1 treble
%%MIDI program 66
d2d|B2B2-|Bd2B|A2A2-|Ad2B|
AFD2-|DE2F|D4-|Dzz2||
V:2 perc
K:C
%%staffscale 0.8
%%MIDI channel 10
%%voicemap drumset
z2z | ^D,^D,^D,^D, & [I:MIDI=channel 10]C,,E,,C,,E,, | ^D,^D,^D,^D, & C,,E,,C,,E,, |\
 ^D,^D,^D,^D, & C,,E,,C,,E,, | ^D,xx2 & C,,E,,/E,,/C,,E,,|
^D,^D,^D,^D, & C,,E,,C,,E,, | ^D,^D,^D,^D, & C,,E,,C,,E,, |\
 ^D,xx2 & C,,E,,/E,,/C,,E,, | ^D,zz2 & C,,xx2||

X:1
T:Schlagzeugstimme (Variante mit \%\%MIDI drummap und \%\%map)
%%map MIDIdrum g heads=x
M:4/4
L:1/4
Q:1/4=180
K:D
V:1 treble
%%MIDI program 66
d2d|B2B2-|Bd2B|A2A2-|Ad2B|
AFD2-|DE2F|D4-|Dzz2||
V:2 perc
K:C
%%staffscale 0.8
%%MIDI channel 10
%%--- Die folgende Zeile ist in neueren Versionen von abc2svg nicht mehr notwendig:
%%voicemap MIDIdrum
%--- voicemap vor drummap setzen!
%%MIDI drummap g 42
%%MIDI drummap c 38
%%MIDI drummap F 36
z2z | gggg & [I:MIDI=channel 10]FcFc | gggg & FcFc |\
 gggg & FcFc | g xx2 & Fc/c/Fc|
gggg & FcFc | gggg & FcFc |\
 g xx2 & Fc/c/Fc | g zz2 & F xx2||

X:1
T:Schlagzeugstimme (Variante mit \%\%percmap und \%\%MIDI drummap)
M:4/4
L:1/4
Q:1/4=180
K:D
V:1 treble
%%MIDI program 66
d2d|B2B2-|Bd2B|A2A2-|Ad2B|
AFD2-|DE2F|D4-|Dzz2||
V:2 perc
K:C
%%staffscale 0.8
%%MIDI channel 10
%%percmap g ride-cymbal-1 x
%%percmap c acoustic-snare
%%percmap F a-b-d %acoustic-bass-drum
%%MIDI drummap g 42
%%MIDI drummap c 38
%%MIDI drummap F 36 
z2z | gggg & [I:MIDI=channel 10]FcFc | gggg & FcFc |\
 gggg & FcFc | g xx2 & Fc/c/Fc|
gggg & FcFc | gggg & FcFc |\
 g xx2 & Fc/c/Fc | g zz2 & F xx2||

X:1
T:Percussion mit program changes 112-119
M:4/4
L:1/8
Q:1/4=120
K:C
V:1
%%MIDI program 74
c2c2d2d2|e2eee2z2||
V:2 clef=perc
%%MIDI program 116
%%stafflines 1
%%staffscale 0.8
z2 (3GGG z2G2|z2GGG2z2||
V:3 clef=perc
%%MIDI program 117
%%stafflines 1
%%staffscale 0.8
C2z2C2z2|C2z2C2z2||

X:1
T:Schlagzeugstimme ABCJS
M:4/4
L:1/4
Q:1/4=180
K:D
V:1 treble
%%MIDI program 66
d2d|B2B2-|Bd2B|A2A2-|Ad2B|
AFD2-|DE2F|D4-|Dzz2||
K:C
V:2 perc
K:C
%%MIDI channel 10
z2z | ^D,^D,^D,^D, & C,,E,,C,,E,, | ^D,^D,^D,^D, & C,,E,,C,,E,, |\
 ^D,^D,^D,^D, & C,,E,,C,,E,, | ^D,xx2 & C,,E,,/E,,/C,,E,,|
^D,^D,^D,^D, & C,,E,,C,,E,, | ^D,^D,^D,^D, & C,,E,,C,,E,, |\
 ^D,xx2 & C,,E,,/E,,/C,,E,, | ^D,zz2 & C,,xx2||